100 REM VIC/64 DISK MENU:PRINTCHR$(14)
120 PRINT"":POKE53280,0:POKE53281,0
130 PRINT"[147]READING DISK DIRECTORY[158] "
140 DIMP$(100)
150 REM DIRECTORY
160 REM  PEEPER
170 OPEN1,8,0,"$"
180 REM LOAD ARRAY P$
190 GET#1,B$:IFST<>0THEN270
200 IFB$<>CHR$(34)THEN190
210 P$=""
220 GET#1,B$:IFB$<>CHR$(34)THENP$=P$+B$:GOTO220
230 GET#1,B$:IFB$=CHR$(32)THEN230
240 P$(X)=P$
250 GET#1,B$:IFB$<>"" THEN250
260 IFST=0THENX=X+1:GOTO180
270 CLOSE1
280 REM  DISPLAY MENU
290 N=10
300 PRINT"[147][159] [195]OMMODORE [213]SERS OF [206]ORMAN [204]IBRARY [196]ISK [158]"
310 PRINT"  ";P$(0);"":PRINT
320 IFN<10THENN=10
330 IFN>100THENN=100
340 FORJ=(N-9)TON:PRINTJ;"- ";P$(J):NEXTJ
350 PRINT:PRINT"PRESS[157][157][157][157][157]     [159]N[146]EXT SCREEN   [146]";
360 PRINT"    [159]L[146]AST SCREEN[146]"
370 PRINT"     [159]E[146][158]XIT TO BASIC [146]";
380 PRINT"    [159]S[146][158] LOAD ONLY[146]"
390 PRINT"     [159]R[146] LOAD AND RUN[146]"
400 Z$="":GETZ$:IFZ$=""THEN400
410 IFZ$="N"THENN=N+10:GOTO300
420 IFZ$="L"THENN=N-10:GOTO300
430 IFZ$="E"THENPRINT"MENU STILL PRESENT":END
440 IFZ$="S"THENGOSUB470:GOTO570
450 IFZ$="R"THENGOSUB470:GOTO540
460 GOTO400
470 REM SELECT AND            PRINT LOAD
480 PRINT"PROGRAM #";
490 INPUTS:PRINT""
500 IFS<1ORS>XTHEN480
510 IFLEN(P$(S))>12THENP$(S)=LEFT$(P$(S),12)+"*"
520 PRINT"LOAD"+CHR$(34)+P$(S)+CHR$(34)+",8,1[145][145][145]"
530 RETURN
540 REM LOAD AND RUN
550 POKE631,13:POKE632,82:POKE633,85:POKE634,78:POKE635,13:POKE198,5
560 END
570 REM LOAD ONLY
580 POKE631,13:POKE198,1